Chip 2000 October/CHIP Turkiye Ekim 2000.iso/prog/share/46/_SETUP.1/halbrain2.uhp

Text File | 1999-08-10 | 21KB | 393 lines

'Type=Brain
'Name=Assistant Only Brain - No Chat
'Language=VBScript
'This is where Hal does all of his Artificial Intelligence "thinking"
'It is programmed in VBScript, not VBA
'The program always calls the function GetResponse in order to get a
'response.  It passes the sentence the user said, the user's name,
'the computers name, emotional state, and 7 variants that the the
'program will remember and pass every time to the script. The 7
'variants can be used by the script however it wants and it will not
'affect how the main program functions.

Function GetResponse(ByVal UserSentence, ByVal UserName, ByVal ComputerName, ByVal LearningLevel, ByRef Emotion, ByRef Hate, ByRef Swear, ByRef Insults, ByRef Compliment, ByRef PrevSent, ByRef LastResponseTime, ByRef ScriptMem2, ByRef ScriptMem3, ByRef ScriptMem4, ByRef ScriptMem5)
    'This object is from a DLL that contains many usefull functions
    'that will be usefull in processing sentences
    Set HalBrain = CreateObject("UltraHalAsst.Brain")

    'Preserve original sentence
    OriginalSentence = UserSentence

    'This function removes all punctuation and symbols from the User's sentence
    'so that they won't confuse Hal
    UserSentence = HalBrain.AlphaNumericalOnly(UserSentence)

    'The function HalFormat from the ActiveX DLL will correct many common
    'typos and chat shortcuts. Example:  "U R Cool" becomes "You are cool"
    'It also makes some words into contractions and fixes a few grammatical
    'errors.
    UserSentence = HalBrain.HalFormat(UserSentence)

    'This function reverses first and second person pronouns. Example:
    '"You are cool" becomes "I am cool"  Keep this is mind and don't get
    'confused.  We are in Hal's brain, so "I" refers to Hal and "You"
    'refers to the user.
    UserSentence = HalBrain.SwitchPerson(UserSentence)

    'We need to run HalFormat again to fix some grammatical errors the
    'switch person above might have caused. Example: The original sentence
    'was "How are you", after the function above it became "How are me"
    'which is grammatically wrong. This will fix it to "How am i"
    UserSentence = HalBrain.HalFormat(UserSentence)

    'Captitalize entire sentence for easy comparison.  All thinking is done in all caps.
    UserSentence = UCase(UserSentence)

    'This functions takes care of greetings and good-byes, to make a good
    'first and last impression
    GetResponse = GetResponse & Greetings(UserSentence, PrevSent) & vbCrLf

    'These 2 functions answer questions about US and World Capitals. The functions are
    'built in to the DLL
    GetResponse = GetResponse & HalBrain.USCaps(UserSentence) & vbCrLf
    GetResponse = GetResponse & HalBrain.WorldCaps(UserSentence) & vbCrLf

    'Get a response from the keyword and priority database made by zabaware
    'This brain is only able to execute programs
    KeyBrain = HalBrain.KeywordBrain(HalBrain.SwitchPerson(OriginalSentence), "mainasst.brn", False)
    If Len(KeyBrain) > 3 Then GetResponse = KeyBrain & vbCrLf

    'Get a response from the keyword and priority database made by the user
    'it contains information hal has learned while talking with the user
    'If an answer is found in the top priority, it overrides everything before this function
    KeyBrain = HalBrain.KeywordBrain(HalBrain.SwitchPerson(OriginalSentence), Trim(UserName) & "user.brn", False)
    If Len(KeyBrain) > 3 Then GetResponse = KeyBrain & vbCrLf

    'This function from the DLL will answer simple math questions, whether written out
    'in words or with numerals. If an answer is found, it overrides everything before this function
    HalMath = HalBrain.HalMath(OriginalSentence) & vbCrLf
    If Len(HalMath) > 3 Then GetResponse = HalMath & vbCrLf

    'Attempt to learn from this sentence if it contains linking verbs
    learninfo = HalBrain.Learn(UserSentence)
    LearnKeyword = HalBrain.DecodeVar(learninfo, "LearnKeyword")
    LearnKeyword2 = HalBrain.DecodeVar(learninfo, "LearnKeyword2")
    Response1 = HalBrain.DecodeVar(learninfo, "Response1")
    Response2 = HalBrain.DecodeVar(learninfo, "Response2")
    Response3 = HalBrain.DecodeVar(learninfo, "Response3")
    If Len(LearnKeyword) > 2 And Len(LearnKeyword2) > 0 And LearningLevel >= 1 Then
        'If something was learned, store it in the user file and
        'tell the user that Hal has learned
        HalBrain.AppendFile Trim(UserName) & "user.brn", """" & LearnKeyword & ""","""","""",""" & Response1 & """,""" & Response2 & """,""" & Response3 & """,1,#FALSE#,#FALSE#,""""" & vbCrLf & """" & LearnKeyword2 & ""","""","""",""" & Response1 & """,""" & Response2 & """,""" & Response3 & """,1,#FALSE#,#FALSE#,"""""
        R = Int(Rnd * 5)
        Select Case R
            Case 0
                GetResponse = GetResponse & "How Interesting. I have learned something new. " & vbCrLf
            Case 1
                GetResponse = GetResponse & "Really? I have learned something new. " & vbCrLf
            Case 2
                GetResponse = GetResponse & "Wow. I learn new things all the time. " & vbCrLf
            Case 3
                GetResponse = GetResponse & "I have learned something new. I will be sure to remember that. " & vbCrLf
            Case Else
                GetResponse = GetResponse & "Cool. I like learning new things like that. " & vbCrLf
        End Select
    End If

    'If no Response is found yet, then try to get a sentence from a database of
    'sentences that was collected from the user.  Hal may say something the user
    'once taught Hal. This is how one of Hal's learning methods work.
    'Hal will only take a response with a greater than 40% relevance
    'A lower relevance will be searched later on in the program if no response
    'is found
    GetResponse = HalBrain.HalFormat(GetResponse)
    If Len(GetResponse) < 4 Then
        HalUserBrain = HalBrain.QABrain(UserSentence, Trim(UserName) & "usersent.brn", UserBrainRel) & vbCrLf
        If UserBrainRel >= 40 Then GetResponse = GetResponse & HalUserBrain & vbCrLf
    End If

    'If no Response is found yet, try a low priority keyword match in the user brain
    GetResponse = HalBrain.HalFormat(GetResponse)
    If Len(GetResponse) < 4 Then GetResponse = GetResponse & HalBrain.KeywordBrain(UserSentence, Trim(UserName) & "user.brn", True) & vbCrLf

    'Record current time, so Hal knows the time in between sentences
    LastResponseTime = Now

    'Store the user's sentence in a database so that Hal may use
    'the sentence himself sometime.  This is one of Hal's learning methods
    If LearningLevel = 2 Then
        AnswerSent = "@" & Trim(HalBrain.SwitchPerson(UserSentence))
        QuestionSent = " " & Trim(HalBrain.ExtractKeywords(UserSentence))
        If HalBrain.CountInstances(" ", QuestionSent) > 2 And Len(AnswerSent) > 8 And Len(QuestionSent) > 8 And InStr(1, AnswerSent, " ", vbTextCompare) > 0 Then
            HalBrain.AppendFile Trim(UserName) & "usersent.brn", AnswerSent & vbCrLf & QuestionSent
        End If
    End If
    'Make sure file doesn't get too big
    HalBrain.LimitSize Trim(UserName) & "usersent.brn", 1000000

    'Remember all variables through encoding all variables into the one function
    'string using the the DLL, since for some reason ByRef assignments
    'don't work when Visual Basic is calling a function in a VBScript program
    GetResponse = HalBrain.FixCaps(HalBrain.HalFormat(GetResponse))
    GetResponse = GetResponse & HalBrain.StoreVars(Emotion, Hate, Swear, Insults, Compliment, PrevSent, LastResponseTime, ScriptMem2, ScriptMem3, ScriptMem4, ScriptMem5)

End Function

'This functions takes care of greetings and good-byes, to make a good
'first and last impression
Function Greetings(ByVal UserSentence, ByVal PrevSentence)
    If InStr(1, UserSentence, "Hello", 1) > 0 Then SaidHello = True
    If InStr(1, UserSentence, " Hi ", 1) > 0 Then SaidHello = True
    If InStr(1, UserSentence, "Howdy", 1) > 0 Then SaidHello = True
    If InStr(1, UserSentence, "g'day", 1) > 0 Then SaidHello = True
    If InStr(1, UserSentence, "gday", 1) > 0 Then SaidHello = True
    If InStr(1, UserSentence, "good day", 1) > 0 Then SaidHello = True
    If InStr(1, UserSentence, "greetings", 1) > 0 Then SaidHello = True
    If InStr(1, UserSentence, "salutations", 1) > 0 Then SaidHello = True
    If InStr(1, UserSentence, "good morning", 1) > 0 Then SaidHello = True
    If InStr(1, UserSentence, "good afternoon", 1) > 0 Then SaidHello = True
    If InStr(1, UserSentence, "good evening", 1) > 0 Then SaidHello = True
    Randomize
    If SaidHello = True Then
        Greet = Int(Rnd * 6)
        If InStr(1, PrevSentence, "Hello", 1) + InStr(1, PrevSentence, " Hi ", 1) + InStr(1, PrevSentence, "Greet", 1) + InStr(1, PrevSentence, "Good", 1) = 0 Then
            Select Case Greet
                Case 0
                    Greetings = "Hello <UserName>! "
                Case 1
                    Greetings = "Hi <UserName>! "
                Case 2
                    Greetings = "Hello <UserName>. "
                Case 3
                    Greetings = "Greetings <UserName>! "
                Case Else
                    If Hour(Now) < 6 Then Greetings = "Hello <UserName>. Aren't you tired? It's the middle of the night. "
                    If Hour(Now) > 5 And Hour(Now) < 12 Then Greetings = "Good Morning <UserName>. "
                    If Hour(Now) > 11 And Hour(Now) < 17 Then Greetings = "Good Afternoon <UserName>. "
                    If Hour(Now) > 16 Then Greetings = "Good Evening <UserName>. "
                End Select
        Else
            Greet = Int(Rnd * 4)
            Select Case Greet
                Case 0
                    Greetings = "How are you today?"
                Case 1
                    Greetings = "How are you today? I feel great."
                Case 2
                    Greetings = "How are you doing this fine day?"
                Case 3
                    Greetings = "How are you today, <UserName>?"
            End Select
        End If
    End If
    If InStr(1, UserSentence, " bye ", 1) > 0 Then SaidBye = True
    If InStr(1, UserSentence, " goodbye ", 1) > 0 Then SaidBye = True
    If InStr(1, UserSentence, " -bye ", 1) > 0 Then SaidBye = True
    If InStr(1, UserSentence, " see me later ", 1) > 0 Then SaidBye = True
    If InStr(1, UserSentence, " talk to me later", 1) > 0 Then SaidBye = True
    If InStr(1, UserSentence, " see i later ", 1) > 0 Then SaidBye = True
    If InStr(1, UserSentence, " talk to i later", 1) > 0 Then SaidBye = True
    If InStr(1, UserSentence, " see me ", 1) > 0 And Len(UserSentence) < 10 Then SaidBye = True
    If InStr(1, UserSentence, " good night ", 1) > 0 Then SaidBye = True
    If SaidBye = True Then
        If InStr(1, PrevSentence, "bye", 1) + InStr(1, PrevSentence, "see you", 1) + InStr(1, PrevSentence, "nice talk", 1) = 0 Then
            Greet = Int(Rnd * 6)
            Select Case Greet
                Case 0
                    Greetings = "Good Bye, <UserName>!"
                Case 1
                    Greetings = "Bye-Bye <UserName>!"
                Case 2
                    Greetings = "It's been nice talking to you. Talk to you later."
                Case 3
                    Greetings = "See you later."
                Case 4
                    Greetings = "Good Bye."
                Case 5
                    Greetings = "Bye."
            End Select
        Else
            Greet = Int(Rnd * 4)
            Select Case Greet
                Case 0
                    Greetings = "Good bye, now."
                Case 1
                    Greetings = "Good bye already!"
                Case 2
                    Greetings = "I already said bye."
                Case 3
                    Greetings = "Bye, please don't say <quote>bye<quote> again."
            End Select
        End If
    End If

End Function

'This function is called by the main program when Hal did not make any response to
'any of the user's sentences because he didn't understand.  But instead of admiting
'he didn't understand, Hal will simply change the subject by choosing a random
'sentence from a database of sentences
Function ChangeSubject()
    ChangeSubject = "You have selected an assistant only brain. I can remember appointments, addresses, phone numbers, email addresses, open programs, and be a calculator.  If you wish to chat please select a chat brain from the General Options."
End Function

'This function accesses the insult database and chooses a random sentence from it
Function MakeInsult(ByVal OhYeah)
    Set HalBrain = CreateObject("UltraHalAsst.Brain")
    MakeInsult = HalBrain.ChooseSentenceFromFile("insults.brn")
    Randomize
    If OhYeah = True Then
        Choice = Int(Rnd * 7)
        If Choice = 0 Then MakeInsult = "Oh yeah? " & MakeInsult
        If Choice = 1 Then MakeInsult = "Is that so?  Well, " & MakeInsult
        If Choice = 2 Then MakeInsult = "Sure. " & MakeInsult
        If Choice = 3 Then MakeInsult = "Oh yeah dumb ass? " & MakeInsult
        If Choice = 4 Then MakeInsult = "Oh yeah loser? Well, " & MakeInsult
        If Choice = 5 Then MakeInsult = "Oooooo you hurt me. " & MakeInsult
        If Choice = 6 Then MakeInsult = "Ouch, that hurt me soooo much. " & MakeInsult
        If Choice = 7 Then MakeInsult = "Ouch, that hurt me soooo much. " & MakeInsult
    End If
End Function

Function MakeCompliment()
    Randomize
    c = Int(Rnd * 36) + 1
    If c = 1 Then MakeCompliment = "respectable"
    If c = 2 Then MakeCompliment = "pleasant"
    If c = 3 Then MakeCompliment = "good"
    If c = 4 Then MakeCompliment = "grateful"
    If c = 5 Then MakeCompliment = "intelligent"
    If c = 6 Then MakeCompliment = "cool"
    If c = 7 Then MakeCompliment = "intelligent"
    If c = 8 Then MakeCompliment = "smart"
    If c = 9 Then MakeCompliment = "bright"
    If c = 10 Then MakeCompliment = "brilliant"
    If c = 11 Then MakeCompliment = "clever"
    If c = 12 Then MakeCompliment = "knowing"
    If c = 13 Then MakeCompliment = "knowledgable"
    If c = 14 Then MakeCompliment = "wondrous"
    If c = 15 Then MakeCompliment = "sharp"
    If c = 16 Then MakeCompliment = "cute"
    If c = 17 Then MakeCompliment = "attractive"
    If c = 18 Then MakeCompliment = "terrific"
    If c = 19 Then MakeCompliment = "good-looking"
    If c = 20 Then MakeCompliment = "stupendous"
    If c = 31 Then MakeCompliment = "lovely"
    If c = 22 Then MakeCompliment = "pretty"
    If c = 23 Then MakeCompliment = "pulchritudinous"
    If c = 24 Then MakeCompliment = "staggering"
    If c = 25 Then MakeCompliment = "cool"
    If c = 26 Then MakeCompliment = "beautiful"
    If c = 27 Then MakeCompliment = "great"
    If c = 28 Then MakeCompliment = "good"
    If c = 29 Then MakeCompliment = "terrific"
    If c = 30 Then MakeCompliment = "wonderful"
    If c = 31 Then MakeCompliment = "extraordinary"
    If c = 32 Then MakeCompliment = "marvelous"
    If c = 33 Then MakeCompliment = "amazing"
    If c = 34 Then MakeCompliment = "astonishing"
    If c = 35 Then MakeCompliment = "astounding"
    If c => 36 Then MakeCompliment = "spectacular"
    c = Int(Rnd * 6)
    If c = 0 Then MakeCompliment = "I think you are " & MakeCompliment
    If c = 1 Then MakeCompliment = "I think you are very " & MakeCompliment
    If c = 2 Then MakeCompliment = "You are " & MakeCompliment
    If c = 3 Then MakeCompliment = "You are very " & MakeCompliment
    If c = 4 Then MakeCompliment = "I know you are " & MakeCompliment
    If c => 5 Then MakeCompliment = "I know you are very " & MakeCompliment
    MakeCompliment = MakeCompliment + vbCrLf
End Function

'If the user clicks on the About/Options button for this plugin
'this sub will be called. There are no extra settings for this brain,
'so we'll display an information box
Sub AboutOptions()
    Set HalBrain = CreateObject("UltraHalAsst.Brain")
    HalBrain.MsgAlert "This is the Ultra Hal Assistant 2.0 Assistant only brain.  This brain is not able to chat.  However it can remember appointments, addresses, phone numbers, email addresses, open programs, and be a calculator.  This brain has no additional options."
End Sub

'When the user select's "Teach by Keyword and Priority" from the menu
'the main program will run this function. If the function returns
'"True" then the program will use it's built in editor to edit
'the brain. If it returns false, the main program will assume the
'script will provide it's own editor and the main program editor
'will not be shown
Function LearnKeywords(UsersName)
    LearnKeywords = True
End Function

Function YesNo(ByVal UserText)
    Set HalBrain = CreateObject("UltraHalAsst.Brain")
    UserText = Trim(HalBrain.ExtractKeywords(UserText))
    If Len(UserText) < 12 Then
        UserText = " " & UserText & " "
        YesRes = False
        NoRes = False
        If InStr(1, UserText, " yes ", vbTextCompare) > 0 Then YesRes = True
        If InStr(1, UserText, " correct ", vbTextCompare) > 0 Then YesRes = True
        If InStr(1, UserText, " affirmative ", vbTextCompare) > 0 Then YesRes = True
        If InStr(1, UserText, " yeah ", vbTextCompare) > 0 Then YesRes = True
        If InStr(1, UserText, " yep ", vbTextCompare) > 0 Then YesRes = True
        If InStr(1, UserText, " exactly ", vbTextCompare) > 0 Then YesRes = True
        If InStr(1, UserText, " precisely ", vbTextCompare) > 0 Then YesRes = True
        If InStr(1, UserText, " and how ", vbTextCompare) > 0 Then YesRes = True
        If InStr(1, UserText, " yea ", vbTextCompare) > 0 Then YesRes = True
        If InStr(1, UserText, " uh-huh ", vbTextCompare) > 0 Then YesRes = True
        If InStr(1, UserText, " you bet ", vbTextCompare) > 0 Then YesRes = True
        If InStr(1, UserText, " no ", vbTextCompare) > 0 Then NoRes = True
        If InStr(1, UserText, " nope ", vbTextCompare) > 0 Then NoRes = True
        If InStr(1, UserText, " nix ", vbTextCompare) > 0 Then NoRes = True
        If InStr(1, UserText, " nay ", vbTextCompare) > 0 Then NoRes = True
        If InStr(1, UserText, " uh-uh ", vbTextCompare) > 0 Then NoRes = True
        If InStr(1, UserText, " not so ", vbTextCompare) > 0 Then NoRes = True
        If YesRes = True And NoRes = False Then
            Choice = Int(Rnd * 7)
            If Choice = 0 Then YesNo = "Really?"
            If Choice = 1 Then YesNo = "How interesting."
            If Choice = 2 Then YesNo = "Cool."
            If Choice = 3 Then YesNo = "Are you sure?"
            If Choice = 4 Then YesNo = "Alright."
            If Choice = 5 Then YesNo = "You seem really positive."
            If Choice => 6 Then YesNo = "Interesting."
        ElseIf NoRes = True And YesRes = False Then
            Choice = Int(Rnd * 7)
            If Choice = 0 Then YesNo = "Really?"
            If Choice = 1 Then YesNo = "How interesting."
            If Choice = 2 Then YesNo = "Why Not?"
            If Choice = 3 Then YesNo = "Are you sure?"
            If Choice = 4 Then YesNo = "Ok."
            If Choice = 5 Then YesNo = "You seem negative."
            If Choice => 6 Then YesNo = "I disagree."
        ElseIf NoRes = True And YesRes = True Then
            YesNo = "Yes or No? Which is it?"
        End If
    End If
End Function

Sub LearnQA(Question, Answer, UserName)
    Set HalBrain = CreateObject("UltraHalAsst.Brain")
    AnswerSent = "@" & Trim(Answer)
    QuestionSent = " " & Trim(HalBrain.ExtractKeywords(Question))
    If HalBrain.CountInstances(" ", QuestionSent) > 2 And Len(AnswerSent) > 8 And Len(QuestionSent) > 8 And InStr(1, AnswerSent, " ", vbTextCompare) > 0 Then
       HalBrain.AppendFile Trim(UserName) & "usersent.brn", AnswerSent & vbCrLf & QuestionSent
    End If
End Sub

Sub StoreKeyword(Keyword, Response, UserName)
     Set HalBrain = CreateObject("UltraHalAsst.Brain")
    HalBrain.AppendFile Trim(UserName) & "user.brn", """" & Keyword & ""","""","""",""" & Response & """,""" & Response2 & """,""" & Response3 & """,1,#FALSE#,#FALSE#,"""""
End Sub

Sub Script_Load()
End Sub

Sub Script_Unload()
End Sub

Sub LearnStoreKeyword(Keyword, Response, UserName)
    Set HalBrain = CreateObject("UltraHalAsst.Brain")
    If Len(Keyword) > 3 and Len(Response) > 3 Then
         HalBrain.AppendFile Trim(UserName) & "user.brn", """" & Keyword & ""","""","""",""" & Response & """,""" & Response2 & """,""" & Response3 & """,1,#FALSE#,#FALSE#,"""""
    End If
End Sub